render_face_poses.gd

## Visual test: face closeups of baked poses applied through the facial controller.
## Run windowed:  godot --resolution 360x360 -s tests/render_face_poses.gd
extends SceneTree

const POSES := ["Neutral", "Happy", "Angry", "Surprised", "Blink", "EyeLeft", "EyeRight", "EyeUp", "EyeDown"]

func _init() -> void:
	call_deferred("_run")


func _run() -> void:
	var library := SKPartLibrary.new()
	library.scan()
	var colors := SKColorEngine.new()
	colors.setup()
	var recipe := SKRecipe.new()
	recipe.parts.append({ "name": "SK_HUMN_BASE_01_01HEAD_HU01" })
	var character := SKCharacterBuilder.new(library, colors).build(recipe)
	if character == null:
		printerr("build failed")
		quit(1)
		return
	root.add_child(character)
	var controller := SidekickFacialController.new()
	controller.name = "FacialController"
	character.add_child(controller)

	var light := DirectionalLight3D.new()
	light.rotation_degrees = Vector3(-30, 20, 0)
	light.light_energy = 1.2
	root.add_child(light)
	var environment := WorldEnvironment.new()
	var env := Environment.new()
	env.background_mode = Environment.BG_COLOR
	env.background_color = Color(0.2, 0.22, 0.25)
	env.ambient_light_source = Environment.AMBIENT_SOURCE_COLOR
	env.ambient_light_color = Color(0.7, 0.7, 0.75)
	env.ambient_light_energy = 0.6
	environment.environment = env
	root.add_child(environment)
	var camera := Camera3D.new()
	camera.look_at_from_position(Vector3(0, 1.62, 0.45), Vector3(0, 1.6, 0))
	camera.fov = 30
	root.add_child(camera)
	camera.make_current()

	SKFacePoses.bake()
	for pose_name in POSES:
		controller.apply_pose(SKFacePoses.get_pose(pose_name))
		controller.apply()
		for i in 6:
			await process_frame
		root.get_viewport().get_texture().get_image().save_png("user://face_%s.png" % pose_name.to_lower())
	print("saved")
	quit(0)